Fonctions de Chaînes

Dans ce chapitre, vous allez apprendre à manipuler des chaînes. AMOS Professional Basic dispose d'un ensemble complet d'instructions de manipulation de chaînes, et les programmeurs Basic expérimentés devraient déjà être familiers avec la syntaxe standard utilisée.

Lire les caractères d'une chaîne

LEFT$
fonction : renvoyer les caractères les plus à gauche d'une chaîne
destination$=Left$(source$,nombre)
Left$(destination$,nombre)=source$

LEFT$ lit le nombre spécifié de caractères dans une chaîne source, en commençant par le côté gauche, et les copie dans une chaîne de destination. Le premier type d'utilisation de cette fonction crée une nouvelle chaîne de destination à partir du nombre de caractères choisi dans la chaîne source. Par exemple :

E> Do
    Input "Tapez une chaîne de caractères :";S$
    Print "Afficher combien de caractères depuis"
    Input "la gauche ?";N
    Print Left$(S$,N)
   Loop

Le second type d'utilisation remplace le nombre de caractères les plus à gauche dans la chaîne de destination par le nombre équivalent de caractères provenant de la chaîne source. Par exemple :

E> A$="**** Basic"
   Left$(A$,4)="AMOS"
   Print A$

Les mêmes opérations peuvent être effectuées avec les caractères à partir du côté droit d'une chaîne, en utilisant la fonction équivalente RIGHT$.

RIGHT$
fonction : renvoyer les caractères les plus à droite d'une chaîne
destination$=Right$(source$,nombre)
Right$(destination$,nombre)=source$

Voici deux exemples illustrant chaque type d'utilisation :

E> Print Right$("IGNORED54321",5)
   A$=Right$("REJECTED0123456789",10)
   Print A$

E> B$="AMOS ************"
   Right$(B$,12)="Professsional"
   Print B$